Gravestone mod - Graves

Gravestone mod - Graves

Mods
4M Downloads

[1.7.10] Unable to craft skull candles with Forestry candles.

AnrDaemon opened this issue ยท 1 comments

commented

GraveStone 2.16.1
Forestry 4.2.14.62

Unable to make skull candles using Forestry candles. Lit/unlit, doesn't matter.

commented 
import minetweaker.item.IItemStack;

<ore:candle>.add(<GraveStone:GSCandle>);
<ore:candle>.add(<Forestry:candle:*>);
<ore:candle>.add(<Thaumcraft:blockCandle:*>);

val skulls = [
  <GraveStone:GSSkullCandle>,
  <GraveStone:GSSkullCandle:1>,
  <GraveStone:GSSkullCandle:2>,
] as IItemStack[];

recipes.removeShaped(<GraveStone:GSCandle>);
recipes.addShaped(<GraveStone:GSCandle>, [[<minecraft:string>],[<ore:dyeWhite>],[<ore:slimeball>]]);

for skull in skulls {
  recipes.removeShaped(skull);
}

recipes.addShaped(<GraveStone:GSSkullCandle>, [[<ore:candle>], [<minecraft:skull>]]);
recipes.addShaped(<GraveStone:GSSkullCandle:1>, [[<ore:candle>], [<minecraft:skull:1>]]);
recipes.addShaped(<GraveStone:GSSkullCandle:2>, [[<ore:candle>], [<minecraft:skull:2>]]);