Mechanical Squeezer Isn't Craftable
mataramosiki opened this issue · 4 comments
Modpack version
Input version here
1.35
Issue
Input short description of the issue here
In enigmatica 2 expert skyblock it lets me put in the material for the Mechanical Squeezer into the crafting table, however, an output is not created.
Logs
Input pastebin link to crash-report or latest log, if applicable
Thanks for the report. This issue also popped up on E2E, so I know what's wrong :)
I can't promise it ever will be to be honest, I don't have time to maintain this modpack :/
However, to fix it manually you can replace the contents of the file scripts/IntegratedDynamics.zs with this:
import crafttweaker.item.IItemStack as IItemStack;
import mods.jei.JEI.removeAndHide as rh;
#modloaded integrateddynamics
print("--- loading IntegratedDynamics.zs ---");
/*
# Aluminum / Osmium Squeezer Compatibility
mods.integrateddynamics.Squeezer.addRecipe(<mekanism:oreblock>, <mekanism:dust:2>, 75, <mekanism:dust:2>);
mods.integrateddynamics.Squeezer.addRecipe(<thermalfoundation:ore:4>, <thermalfoundation:material:68>, 75, <mekanism:dust:2>);
mods.integrateddynamics.MechanicalSqueezer.addRecipe(<mekanism:oreblock>, <mekanism:dust:2> * 2, 50, <mekanism:dust:2>);
mods.integrateddynamics.MechanicalSqueezer.addRecipe(<thermalfoundation:ore:4>, <thermalfoundation:material:68> * 2, 50, <thermalfoundation:material:68>);
*/
# User
recipes.remove(<integratedtunnels:part_player_simulator_item>);
recipes.addShapeless("IT User",
<integratedtunnels:part_player_simulator_item> * 2,
[<extrautils2:user>.anyDamage(), <extrautils2:user>.anyDamage()]);
# Menril Logs -> Planks
recipes.addShapeless("Menril Planks",
<integrateddynamics:menril_planks> * 2,
[<integrateddynamics:menril_log>]);
# Generator
recipes.remove(<integrateddynamics:coal_generator>);
recipes.addShapedMirrored("IntegratedDynamics Generator",
<integrateddynamics:coal_generator>,
[[<integrateddynamics:crystalized_menril_chunk>, <ic2:te:46>, <integrateddynamics:crystalized_menril_chunk>],
[<integrateddynamics:crystalized_menril_block>, <integrateddynamics:energy_battery>.withTag({}), <integrateddynamics:crystalized_menril_block>],
[<integrateddynamics:crystalized_menril_chunk>, <ic2:te:46>, <integrateddynamics:crystalized_menril_chunk>]]);
# Mechanical Squeezer
recipes.remove(<integrateddynamics:mechanical_squeezer>);
recipes.addShapedMirrored("IntegratedDynamics Mechanical Squeezer",
<integrateddynamics:mechanical_squeezer>,
[[<ore:dustDiamond>, <integrateddynamics:squeezer>, <ore:dustDiamond>],
[<integrateddynamics:energy_battery>.withTag({}), <integrateddynamics:squeezer>, <integrateddynamics:energy_battery>.withTag({})],
[<ore:plateObsidian>, <integrateddynamics:squeezer>, <ore:plateObsidian>]]);
# Mechanical Drying Basin
recipes.remove(<integrateddynamics:mechanical_drying_basin>);
recipes.addShapedMirrored("IntegratedDynamics Mechanical Drying Basin",
<integrateddynamics:mechanical_drying_basin>,
[[<ore:plateObsidian>, <integrateddynamics:drying_basin>, <ore:plateObsidian>],
[<integrateddynamics:energy_battery>.withTag({}), <integrateddynamics:drying_basin>, <integrateddynamics:energy_battery>.withTag({})],
[<ore:plateObsidian>, <integrateddynamics:drying_basin>, <ore:plateObsidian>]]);
print("--- IntegratedDynamics.zs initialized ---");
